#!/usr/bin/perl -w
#
# Copyright (c) 2014  Sulev-Madis Silber <ketas@si.pri.ee>
# All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions
# are met:
# 1. Redistributions of source code must retain the above copyright
#    notice, this list of conditions and the following disclaimer.
# 2. Redistributions in binary form must reproduce the above copyright
#    notice, this list of conditions and the following disclaimer in the
#    documentation and/or other materials provided with the distribution.
#
# THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
# ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
# IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
# ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
# FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
# DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
# OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
# HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
# LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
# OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
# SUCH DAMAGE.
#


use strict;
use warnings FATAL => 'all';

use vars qw(%Info %Debug %config_parms);

use Data::Dumper;
use iButton;


$| = 1;


my ($port) = @ARGV;


die 'config error: no port' unless $port;


$Info{OS_name}                     = $^O;

$Debug{ibutton}                    = 0;

$config_parms{weather_uom_temp}    = 'C';
$config_parms{ibutton_tweak}       = 0;
$config_parms{ibutton_line_length} = 'LONG';
$config_parms{iButton_serial_port} = $port;


sub dumper_oneline
{
	local $Data::Dumper::Indent    = 0;
	local $Data::Dumper::Terse     = 1;
	local $Data::Dumper::Quotekeys = 0;
	local $Data::Dumper::Pair      = '=>';
	
	return Dumper @_;
}


sub _dump
{
	print Dumper [ [ caller 0 ], @_ ];
}


sub proxy_send            { _dump @_; return undef; }
sub proxy_receive         { _dump @_; return ''   ; }
sub iButton_receive_hooks { _dump @_; return undef; }
sub get_tickcount         { _dump @_; return 0    ; }


sub onewire_connect
{
	print "iButton::serial_startup 'iButton'\n";
	
	iButton::serial_startup 'iButton';
}


sub onewire_disconnect
{
	printf "iButton::disconnect = '%s'\n", iButton::disconnect;
}


sub cleanexit
{
	onewire_disconnect;
	
	exit;
}


sub onewire_scan
{
	print "iButton::scan\n";
	
	my @sensors = iButton::scan;
	
	
	foreach my $sensor (@sensors)
	{
		unless (defined $sensor)
		{
			printf "sensor = %s\n", dumper_oneline $sensor;
			
			next;
		}
		
		
		my $id = $sensor->id;
		
		unless (defined $id)
		{
			printf "sensor->id = %s\n", dumper_oneline $id;
			
			next;
		}
		
		$id = uc $id;
		
		
		printf "found slave, id = '%s'\n", $id;
		
		
		if ($id =~ /^10/)
		{
			my $temp = $sensor->read_temperature_hires;
			
			unless (defined $temp)
			{
				printf "id = '%s', sensor->read_temperature_hires = %s\n",
					$id,
					dumper_oneline $temp;
				
				next;
			}
			
			
			if ($temp == 85)
			{
				printf "id = '%s', temp = '%s', sensor error\n",
					$id,
					$temp;
				
				next;
			}
			
			
			printf "TEMP %s %s\n",
				$id,
				$temp;
		}
	}
}


$SIG{$_} = \&cleanexit foreach qw(INT TERM);


onewire_connect;


while (<STDIN>)
{
	if (/^scan$/i)
	{
		onewire_scan;
	}
}


onewire_disconnect;